Specifying --without-sendfile-support to configure has no effect. This is because configure.in incorrectly initialises with_sendfile_support=yes after the command-line arguments have been processed.

This appears to be the case for a whole bunch of options:

--without-ldap-support
--without-ads-support
--without-dnsupdate-support 
--without-pam-for-crypt
--without-sendfile-support

This is because configure.in contains code like this:

  with_sendfile_support=yes
  AC_MSG_CHECKING(whether to check to support sendfile)
  AC_ARG_WITH(sendfile-support,
  [  --with-sendfile-support Check for sendfile support (default=yes)],
  [ case "$withval" in
    yes)
        AC_MSG_RESULT(yes);
        case "$host_os" in
              ...
        esac
        ;;
    *)
        AC_MSG_RESULT(no)
        ;;
    esac],
    AC_MSG_RESULT(yes)
  )

I think instead the right way to handle this is to set the default inside the AC_ARG_WITH() [if you must] and then check/switch on the $with_foo variable outside of the AC_ARG_WITH() call, like this:

  AC_ARG_WITH(sendfile-support,
    [  --with-sendfile-support Check for sendfile support (default=yes)],,
    [with_sendfile_support=yes])
  AC_MSG_CHECKING([whether to check to support sendfile])
  case "$with_sendfile_support" in
     yes)
        AC_MSG_RESULT(yes)
        case "$host_os" in
                ...
        esac
        ;;
     *)
        AC_MSG_RESULT(no)
        ;;
  esac